任务栏出现两个Firefox火狐浏览器图标

发布于 2016-02-14 作者 [重庆SEO]

Firefox火狐浏览器卸载然后重装出现了一个问题,当锁定它到任务栏后,再打开火狐,任务栏出现2个火狐浏览器图标,并不是重叠在一起的。

前段时间好像IE还是火狐出现过类似这个问题,当时没有留下相关记录,所以记不清当时是如何解决的。

网上的解决办法大多数是删除注册表的相关项

删除 (32位系统)
HKEY_CURRENT_USER\SOFTWARE\Mozilla\Firefox\TaskBarIDs
删除 (64位系统)
HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Mozilla\Firefox\TaskBarID

我在Wow6432Node下并没有该项,然后刷新后两个火狐图标的问题依旧存在,然后继续找解决办法 下载了一个bat脚本文件执行后,问题解决了,打开脚本看了下似乎也的确是删除注册表的那两项。

脚本如下,保存为bat执行即可:

@echo off
title 解决火狐任务栏双图标――鱼刺
mode con cols=50 lines=25
color 0a
:-------------------------------------
REM --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", ", ", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
:-------------------------------------- 
goto MENU
:menu
cls
echo.
echo 解决火狐任务栏双图标――鱼刺
echo =================================================
echo.
echo 执行操作成功后关闭浏览器重新固定到任务栏
echo.
echo 1,执行此操作
echo.
echo 2,还原操作
echo.
echo 3,退出
echo.
echo =================================================
echo.
echo 请输入选择项目的序号,按回车键确认:
set /p ID=
if "%id%"=="1" goto cmd1
if "%id%"=="2" goto cmd2
IF "%id%"=="3" exit
PAUSE

:cmd1
echo 删除TaskBarIDs项,该项已备份在当前目录 bak.reg
reg export HKLM\SOFTWARE\Wow6432Node\Mozilla\Firefox\TaskBarIDs bak1.reg
reg delete HKLM\SOFTWARE\Wow6432Node\Mozilla\Firefox\TaskBarIDs /f
reg export HKCU\SOFTWARE\Mozilla\Firefox\TaskBarIDs bak2.reg
reg delete HKCU\SOFTWARE\Mozilla\Firefox\TaskBarIDs /f
PAUSE
goto MENU

:cmd2
echo 还原注册表
reg import bak1.reg
reg import bak2.reg
PAUSE
goto MENU